6scjgw
Last Updated: February 25, 2016
·
214
· zhangtai
Profile

KDE style for Windows - ahk

;KDE Windows
#NoTrayIcon
SetWinDelay,2
CoordMode,Mouse
return
!LButton::
If DoubleAlt
{
    MouseGetPos,,,KDE_id
    PostMessage,0x112,0xf020,,,ahk_id %KDE_id%
    DoubleAlt := false
    return
}
MouseGetPos,KDE_X1,KDE_Y1,KDE_id
WinGet,KDE_Win,MinMax,ahk_id %KDE_id%
If KDE_Win
    return
WinGetPos,KDE_WinX1,KDE_WinY1,,,ahk_id %KDE_id%
Loop
{
    GetKeyState,KDE_Button,LButton,P
    If KDE_Button = U
        break
    MouseGetPos,KDE_X2,KDE_Y2
    KDE_X2 -= KDE_X1
    KDE_Y2 -= KDE_Y1
    KDE_WinX2 := (KDE_WinX1 + KDE_X2)
    KDE_WinY2 := (KDE_WinY1 + KDE_Y2)
    WinMove,ahk_id %KDE_id%,,%KDE_WinX2%,%KDE_WinY2%
}
return
!RButton::
If DoubleAlt
{
    MouseGetPos,,,KDE_id
    WinGet,KDE_Win,MinMax,ahk_id %KDE_id%
    If KDE_Win
        WinRestore,ahk_id %KDE_id%
    Else
        WinMaximize,ahk_id %KDE_id%
    DoubleAlt := false
    return
}
MouseGetPos,KDE_X1,KDE_Y1,KDE_id
WinGet,KDE_Win,MinMax,ahk_id %KDE_id%
If KDE_Win
    return
WinGetPos,KDE_WinX1,KDE_WinY1,KDE_WinW,KDE_WinH,ahk_id %KDE_id%
If (KDE_X1 < KDE_WinX1 + KDE_WinW / 2)
   KDE_WinLeft := 1
Else
   KDE_WinLeft := -1
If (KDE_Y1 < KDE_WinY1 + KDE_WinH / 2)
   KDE_WinUp := 1
Else
   KDE_WinUp := -1
Loop
{
    GetKeyState,KDE_Button,RButton,P
    If KDE_Button = U
        break
    MouseGetPos,KDE_X2,KDE_Y2
    WinGetPos,KDE_WinX1,KDE_WinY1,KDE_WinW,KDE_WinH,ahk_id %KDE_id%
    KDE_X2 -= KDE_X1
    KDE_Y2 -= KDE_Y1
    WinMove,ahk_id %KDE_id%,, KDE_WinX1 + (KDE_WinLeft+1)/2*KDE_X2
                            , KDE_WinY1 +   (KDE_WinUp+1)/2*KDE_Y2
                            , KDE_WinW  -     KDE_WinLeft  *KDE_X2
                            , KDE_WinH  -       KDE_WinUp  *KDE_Y2
    KDE_X1 := (KDE_X2 + KDE_X1)
    KDE_Y1 := (KDE_Y2 + KDE_Y1)
}
return
!MButton::
If DoubleAlt
{
    MouseGetPos,,,KDE_id
    WinClose,ahk_id %KDE_id%
    DoubleAlt := false
    return
}
return
~Alt::
DoubleAlt := A_PriorHotKey = "~Alt" AND A_TimeSincePriorHotkey < 400
Sleep 0
KeyWait Alt
return 
Say Thanks
Respond